PLOT Procedures

(PLOT, PLOT_IO, PLOT_OI, PLOT_OO)

Produce a 2D graph of vector parameters:

PLOT produces a simple XY plot.

PLOT_IO produces an XY plot with logarithmic scaling on the y-axis.

PLOT_OI produces an XY plot with logarithmic scaling on the x-axis.

PLOT_OO produces an XY plot with logarithmic scaling on both the x- and y-axes.


Background	Noclip	Week_Boundary
Box	Nodata	[XYZ]Charsize
Channel	Noerase	[XYZ]Gridstyle
Charsize	Normal	[XYZ]Margin
Charthick	Nsum	[XYZ]Minor
Clip	Polar	[XYZ]Range
Color	Position	[XYZ]Style
Compress	Psym	[XYZ]Tickformat
Data	Solid_Psym	[XYZ]Ticklen
Device	Start_Level	[XYZ]Tickname
DT_Range	Subtitle	[XYZ]Ticks
Font	Symsize	[XYZ]Tickv
Gridstyle	T3d	[XYZ]Title
Linestyle	Thick	[XYZ]Type
Max_Levels	Tickformat	YNozero
Month_Abbr	Ticklen	ZValue
	Title

Example 1

This example shows the most common way to use the PLOT procedure.

x = FINDGEN(37) * 10
y = SIN(x * !Dtor)

; Create a sine wave from 0 to 360 degrees.

PLOT, y

; Plot the sine wave using the default values for the plotting
; keywords.

PLOT, x, y, XRange=[0, 360], Title = 'SIN(X)',$
    XTitle = 'degrees', YTitle = 'sin(x)'

; Plot the sine wave against the x values, change the range of
; the x-axis, and add labels. Notice that PV-WAVE rounds the
; requested range values on the axis to values that give a nice
; looking plotin this case 0 to 400.

PLOT, x, y, XRange = [0, 360], XStyle = 1, $
    XTicks = 6, XMinor = 6, XTitle = $
    '!8degrees', YTitle = '!8sin(x)!3', $
    Title = '!17SIN(X)'

; Use keywords to get the desired style and to add fonts to
; the labels.

PLOTS, [0, 360], [0, 0]

; Plot a base line at 0.

TEK_COLOR

; Set up a predefined color table called tek_color.

POLYFILL, x(0:18), y(0:18), Color = 6

; Fill under the positive half of the curve with solid magenta.

z = COS(x * !Dtor)

; Calculate the cosine of x.

OPLOT, x, z, Linestyle = 2, Color = 3, Thick =4

; Plot the cosine using a thick, dashed line and a different color.

Example 2

This example creates a logarithmic plot.

x = [100, 5000, 20000, 50000, 70000L]
y = [100, 10000, 1100000L, 100000L, 200000L]

; Create the data.

PLOT_OO, x, y, Ticklen = 0.5, Gridstyle = 1,$
    Tickformat = '(I7)', Title = 'TEST PLOT', $
    YRange = [1.e2, 1.e7], YStyle = 1

; Plot the data on a log-log plot, with dotted grid lines. Use a 
; format of I7 for the plot labels.

max_y = MAX(y)

; Get the maximum value of y.

x_max_y = x(WHERE(y EQ max_y))

; Get the value for x when y is at its maximum.

XYOUTS, x_max_y(0), max_y+1.e5, 'Test Max', $
    Alignment = 0.5

; Print Test Max centered at the maximum point.

Example 3

In this example, the cubic spline interpolant to the function

f(x) = 1000sin(1/x²) + cos(10x)

over the interval [1, 21] is plotted using PLOT_IO. This example uses the PV-WAVE:IMSL Mathematics function CSINTERP.

x = FINDGEN(101)/5 + 1

; Generate the abscissas.

y = 1000 * SIN(1/x^2) + COS(10 * x)

; Generate the function values.

pp = CSINTERP(x, y)

; Compute the cubic spline interpolant.

ppval = SPVALUE(FINDGEN(1001)/50 + 1, pp)
PLOT_IO, FINDGEN(1001)/50 + 1, ppval

: Plot the result with logarithmic scaling on the y-axis (see
; Figure 2-67).

Figure 2-67 A plot of the cubic spline interpolant of function f(x) using PLOT_IO.

Figure 2-68 A plot of the cubic spline interpolant of function f(x) using PLOT_IO.

Example 4

This example uses the PV-WAVE:IMSL Mathematics SPVALUE function.

x = FINDGEN(100) * 10

; Generate the abscissas.

y = x + 100 * COS(0.05 * x)

; Generate the function values.

pp = CSINTERP(x, y)

; Compute the cubic spline interpolant.

ppval = SPVALUE(FINDGEN(1000), pp)
PLOT_OI, FINDGEN(1000), ppval, XRange = [10, 1000]

; Plot the result with logarithmic scaling on the x-axis 
; (see Figure 2-69).

Figure 2-69 Semi-logarithmic scaling of f(x) using PLOT_OI.

Figure 2-70 Semi-logarithmic scaling of f(x) using PLOT_OI.

Example 5

This example creates a polar plot.

theta = (FINDGEN(200)/100) * !Pi
r = 2 * SIN(4 * theta)

; Create the data.

PLOT, r, theta, /Polar, XStyle=4, YStyle=4, $
    Title='POLAR PLOT TEST'

; Display a polar plot, disabling the box-style axes.

AXIS, 0, 0, XAxis=0

; Draw an x-axis at the point 0, 0 with tick marks going down.

AXIS, 0, 0, YAxis=0

; Draw a y-axis at the point 0, 0 with tick marks going left.

Example 6

This example creates a plot with multiple axes.

temperature = [50., 40., 35., 60., 40.]
pressure = [1025, 1020, 1015, 1026, 1022]

; Create the data.

PLOT, temperature, YRange=[20., 70], $
    YTitle = 'Degrees Fahrenheit', $
    XTitle = 'Sample Number', $
    Title = 'Sample Data', XMargin = [8, 8], $
    YStyle = 8, Color = 16

; Plot temperature against scale on the left axis.

AXIS, YAxis=1, YRange=[1000, 1040], YStyle=1,$
    YTitle = 'Air Pressure', /Save, Color = 16

; Create the axis for air pressure.

OPLOT, pressure, Linestyle = 2, Color = 6

; Plot air pressure against scale on the right axis.

LEGEND, ['temperature', 'air pressure'], $
    [16, 6], [0, 2], [0, 0], 2.4, 1005, 2

; Display a legend.

Example 7

This example creates a plot with a Date/Time x-axis.

x = VAR_TO_DT(1992,1,1)

; Create a date-time array with the first day of 1992.

x = DTGEN(x, 12, /Month)

; Create an array of date lines with one value for each month.

y = RANDOMU(seed, 12) * 1000

; Create an array of data values ranging from 0 to 1000.

PRINT, !Month_Names
hold_month_names = !Month_Names

; Print the current names for months, and then save them.

FOR i = 0, 11 DO !Month_Names(i) = $
    STRMID(!Month_Names(i), 0, 3)

; Change the names to be 3-letter abbreviations for the months.

ylabels = STRARR(6)
FOR i = 0, 5 DO ylabels(i) = '$' + $
    STRTRIM(string(100L * i * 2), 2)

; Create labels on the y-axis that start with a '$'.

PLOT, x, y, /Month_Abbr, /Box, $
    Title='Test Date Plot', YRange=[0, 1000],$
    YStyle=1, YTickname=ylabels, YTicks=5,$
    YTitle='In thousands', YGridstyle=1, $
    YTicklen=0.5

; Plot the data.

!Month_Names = hold_month_names

; Restore !Month_names to the original.

PLOT Procedures

(PLOT, PLOT_IO, PLOT_OI, PLOT_OO)

Usage

Input Parameters

Keywords

Example 1

Example 2

Example 3

Example 4

Example 5

Example 6

Example 7

See Also