PLOTS Procedure

Plots vectors or points on the current graphics device in either two or three dimensions.

Usage

Input Parameters

A vector parameter providing the x-coordinates of the points to be connected.

If only one parameter is specified, x must be an array of either two or three vectors: (2,*) or (3,*). In this special case, x(0,*) is taken as the x values, x(1,*) is taken as the y values, and x(2,*) is taken as the z values.

y (optional) A vector parameter providing the y-coordinates of the points to be connected.

z (optional) If present, a vector parameter providing the z-coordinates of the points to be connected. If z is not specified, x and y are used to draw lines in two dimensions. z has no effect if the keyword T3d is not specified and the system variable !P.T3d = 0.

Keywords

Keywords let you control many aspects of the plot's appearance. PLOTS keywords are listed below. For a description of each keyword, see

Chapter 3, Graphics and Plotting Keywords


Channel	Fill_Pattern	Orientation	Spacing
Clip	Linestyle	Pattern	Symsize
Color	Line_Fill	PClip	T3d
Data	Noclip	Psym	Thick
Device	Normal	Solid_Psym	Z

Discussion

A valid data coordinate system must be established before PLOTS is called. (A call to PLOT can be used to establish this coordinate system.) Also note that a PV-WAVE window must be open and selected when the call to PLOTS is made for the procedure to work correctly.

The coordinates for PLOTS can be given in data, device, or normalized form using the Data, Device, or Normal keywords.

Example 1

WINDOW
xdata = [.1, .2, .5, .8, .9, .5]
ydata = [.3, .6, .9, .6, .3, .1]
PLOTS, xdata, ydata
PLOTS, xdata, ydata, /Normal
PLOTS, xdata, ydata, Symsize=5.0, Psym=-1,$
    /Normal

Figure 2-79 Connected lines drawn with PLOTS.

Figure 2-80 Connected lines drawn with PLOTS.

Example 2

This example plots a curve in R². Notice that PLOT is first called to set up the two-dimensional coordinate system. Normally, PLOT would be called to perform the entire plot, but for demonstration purposes, PLOTS is used to complete the plot once the coordinate system has been defined.

PLOT, FINDGEN(2), /Nodata, $
    XRange = [-1, 1], YRange = [-1, 1]

; Set up the axes using PLOT.

p = FINDGEN(1000)/999

; Generate data.

x = p * SIN(50 * p)
y = p * COS(50 * p)
PLOTS, x, y

Figure 2-81 Plot of curve in R²using PLOTS.

Figure 2-82 Plot of curve in R²using PLOTS.

Example 3

This example plot a curve in R³. Notice that SURFACE is called initially to set up the three-dimensional coordinate system. It is also important to note that keywords Nodata and Save are used when calling SURFACE, and keyword T3d is used in the call to PLOTS.

SURFACE, FINDGEN(2, 2), /Nodata, /Save, $
    XRange = [-1, 1], YRange = [-1, 1], $
    ZRange = [0, 1]
z = FINDGEN(1000)/999
x = z * SIN(50 * z)
y = z * COS(50 * z)
PLOTS, x, y, z, /T3d

Figure 2-83 Line plot in R³.

Figure 2-84 Line plot in IR³.

PLOTS Procedure

Usage

Input Parameters

Keywords

Discussion

Example 1

Example 2

Example 3

See Also