STRETCH Procedure

Standard Library procedure that linearly expands the range of the color table currently loaded to cover an arbitrary range of pixel values.

STRETCH, low, high

low The lowest pixel value in the selected range; in other words, this is the pixel value that will be displayed with color index 0. (Default: 0)

high The highest pixel value in the selected range; in other words, this is the pixel value that will be the highest color index available on a particular device (normally 255 on an eight-bit plane device). (Default: !D.N_Colors - 1)

None.

STRETCH linearly interpolates new Red, Green, and Blue color vectors between low and high, and then loads them into the image display with LOADCT. The color vectors in the COLORS common block are unchanged.

For example, the command:

STRETCH, 100, 150

expands the color table so that the pixels in the range of 100 to 150 fill the entire color-intensity range.

To revert to a normal color table, call STRETCH with no parameters.

mandril = BYTARR(512, 512)
OPENR, unit, !Data_dir + 'mandril.img',/Get_lun
READU, unit, mandril
FREE_LUN, unit

; Read the image.

WINDOW, /Free, Colors=128, XSize=512, YSize=512
TVSCL, mandril

; Display the original image using 128 colors.

LOADCT, 4
COLOR_PALETTE

; Change the color palette and display it for reference.

!Err = 0
WHILE !Err LE 0 DO BEGIN

CURSOR, x, y, /Change, /Normal
range = FIX(y * 128.0 + 5.0)
STRETCH, 64-range, 64+range

ENDWHILE

; Use the position of the cursor to compress or expand the 

; palette about the middle using the STRETCH function.

A simplified version of STRETCH can be written as:

PRO STRETCH, lo, hi

; Procedure definition.

COMMON colors, r_orig, g_orig, b_orig, r_curr, g_curr, b_curr

; Access the color table common block used by 

; PV-WAVE procedures.

t = BYTSCL(INDGEN(256), Min = lo, Max = hi)

; Make a vector of subscripts into the color table arrays.

TVLCT, r_orig(t), g_orig(t), b_orig(t)

; Load colors from the original tables transformed by t.

RETURN
END

LOADCT, MODIFYCT, TVLCT, WgCtTool

System Variables: !D.N_Colors

For more information about how to access the three color variables in the color table common block, see Retrieving Information About the Current Color Table in Chapter 11 of the PV-WAVE User's Guide.

For more information about stretching color tables, see Stretching the Color Table in Chapter 11 of the PV-WAVE User's Guide.