REGRESS Function

Standard Library function that fits a curve to data using the multiple linear regression method.

result = REGRESS(x, y, wt [, yf, a0, sig, ft, r, rm, c])

x An array containing the independent values. Must be two-dimensional of size m by n, where m is the number of coefficients to be computed, and n is the number of data points.

y A vector containing the dependent values. Must have n elements.

wt A vector of weighting factors for determining the weighting of the multiple linear regression. Must have n elements.

yf (optional) An array containing the calculated values of y. It contains n number of elements

a0 (optional) The constant term (offset) of the output function.

sig (optional) A vector containing the standard deviations for the coefficients.

ft (optional) The value of F in the standard F Test for the goodness of fit.

r (optional) A vector containing the linear correlational coefficients.

rm (optional) The multiple linear correlation coefficient.

c (optional) The value of X² in the Chi-Squared test for the goodness of fit.

result A column vector containing the coefficients ( a₁ to a_m ) of the function in x.

None.

REGRESS performs a multiple linear regression fit to a dataset with a specified function which is linear in the coefficients. The general function is given by:

f(x) = a₀ + a₁x₁ + a₂x₂ + ... a_mx_m

Weighting is useful when you want to correct for potential errors in the data you are fitting to a curve. The weighting factor, wt, adjusts the parameters of the curve so that the error at each point of the curve is minimized. For more information, see the section Weighting Factor, in Volume 1 of this reference.

x = FLTARR(3, 9)
x(0, *) = [0.,1.,2.,3.,4.,10.,13.,17.,20.]
x(1, *) = [0.,3.,6.,9.,12.,15.,18.,19.,20.]
x(2, *) = [0.,4.,8.,12.,13.,14.,15.,18.,20.]
y = [5.,4.,3.,2.,2.,4.,5.,8.,9.]

; Create the data.

wt = FLTARR(9) + 1.0
coeff = REGRESS(x,y,wt,yf,a0,sig,ft,r,rm,c)

; Perform multiple linear regression with no weighting.

PLOT, yf, title='REGRESS EXAMPLE'

; Plot the fitted data.

PRINT, 'Fitted function:'
PRINT, ' f(x) = ',a0,' +', $
coeff(0, 0),' x1 +', $
coeff(0, 1),' x2 +', $
coeff(0, 2),' x3'
PRINT, 'Standard deviations for ' +$
    'coefficients: ', sig
PRINT, 'F Test value:', ft
PRINT, 'Linear correlation coefficients: ', r
PRINT, 'Multiple linear correlation ' + 'coefficient: ', rm
PRINT, 'Chi-squared value: ', c

; Print all the output parameters.

CURVEFIT, GAUSSFIT, POLY_FIT, POLYFITW, SVDFIT

The REGRESS function is adapted from the program REGRES in Data Reduction and Error Analysis for the Physical Sciences, by Philip Bevington, McGraw-Hill, New York, 1969.