POLY_DEV Function

Returns a list of 3D points converted from normal coordinates to device coordinates.

result = POLY_DEV(points [,winx, winy])

points A (3, n) array of points (or vertices) to transform.

winx, winy (optional) The maximum x and y dimension, respectively, in device coordinates. If these parameters are omitted, the values of !D.X_Size and !D.Y_Size are used.

result The list of 3D points that has been converted from normal coordinates to device coordinates. The list is in long integer format.

None.

The program in this example displays a perspective view of a surface from a viewpoint within the data.

PRO poly_demo1
winx = 1000
winy = 750

; Specify the window size.

imgx = 477
imgy = 512

; Specify the image size.

elev_dat = BYTARR(imgx, imgy)
OPENR, 1, !Data_Dir + 'bldr_elev.dat'
READU, 1, elev_dat
CLOSE, 1

; Read in the elevation image data.

landsat = BYTARR(imgx, imgy)
OPENR, 1, !Data_Dir + 'bldr_img7.dat'
READU, 1, landsat
CLOSE, 1

; Read in the Landsat image data.

imgx = 120
imgy = 125
elev_dat = CONGRID(FLOAT(elev_dat), imgx, $
    imgy, /Interp)

; Shrink the elevation data to a 120-by-125 array.

landsat = BYTSCL(CONGRID(FLOAT(landsat), $
    imgx, imgy, /Interp), Top = 127)

; Shrink the Landsat image to a 120-by-125 array and scale the
; image into the range of 0 - 127.

zscale = 0.08

; Define the Z compression factor.

viewpoint = [105.0, 70.0, (5.0 * zscale)]
viewvector = [-10.0, -2.5, -0.75]
perspective = 0.06
izoom = 11.0
viewup = [0.0, 1.0]
viewcenter = [0.5, 0.5]
xr = [0, (imgx - 1)]
yr = [0, (imgy - 1)]
zr = [MIN(elev_dat), MAX(elev_dat)]

; Define the view parameters.

elev_dat = elev_dat * zscale

; Compress the elevation data.

SET_VIEW3D, viewpoint, viewvector, $
    perspective, izoom, viewup, $
    viewcenter, winx, winy, xr, yr, zr

; Set up a 3D view based on eye-point and view vector.

PRINT, "Building polygons ..."
POLY_SURF, elev_dat, vertex_list, $
    polygon_list, pg_num

; Generate the polygons representing the surface.

vertex_list = vertex_list
PRINT, "Normalizing coordinates ..."
vertex_list = POLY_NORM(vertex_list)

; Convert the polygon vertices from data coordinates to normal
; coordinates.

PRINT, "Transforming coordinates ..."
vertex_list = POLY_TRANS(vertex_list, !P.T)

; Transform the new coordinates.

PRINT, "Changing to device coordinates ..."
vertex_list = POLY_DEV(vertex_list, winx, $
    winy)

; Convert the normal coordinates to device coordinates.

WINDOW, XSize=winx, YSize=winy, XPos=10, $
    YPos=50, Colors=128

; Set up a new window for plotting.

PRINT, "Plotting ..."
landsat = POLY_C_CONV(polygon_list, landsat)

; Create an array containing one color for each polygon.

POLY_PLOT, vertex_list, polygon_list, $
    pg_num, winx, winy, landsat, -1, -1

; Plot the surface.

END

For other examples of POLY_DEV, see the sphere_demo2, sphere_demo3, and vol_demo4 demonstration programs in:

(UNIX)wavedir/demo/arl

(OpenVMS)wavedir:[DEMO.ARL]

(Windows)wavedir\demo\arl

Where wavedir is the main PV-WAVE directory.

POLY_NORM, POLY_TRANS

For more information, see Coordinate Conversion in Chapter 7, and Three Graphics Coordinate Systems in Chapter 4, of the PV-WAVE User's Guide.