EXEC_ON_SELECT Procedure (UNIX)

Registers callback procedures on input for a vector of logical unit numbers (LUNs).

EXEC_ON_SELECT, luns, commands

luns Vector of logical unit numbers.

commands Vector of procedure names. It must have the same number of entries as the vector luns.

Widget If present and nonzero, resisters LUNs and commands with the WAVE Widgets or Widget Toolbox event loop (WwLoop or WtLoop).

Just_reg If present and nonzero, registers the unit numbers and callback procedures. Do not wait for any input. This is useful when this procedure is used with widgets.

This procedure checks for input on all the logical unit numbers specified in the luns vector. When there is input available on luns (k), the commands (k) procedure is called with luns (k) as its (only) argument. This procedure never returns; it just keeps handling callbacks when input is available.

When used with the WAVE Widgets applications (i.e., when the Widget and Just_reg keywords are used), the callback procedures must have the following parameters:

top, data, nparams, id, lun, source 

Refer to Example 2 for more information.

In this example, three servers are started and their output handled using EXEC_ON_SELECT. For simplicity, the servers are all the same program, EX1, with a different command line argument. The servers occasionally output a four-byte integer. This input is handled by the callback procedures SERVER1, SERVER2, SERVER3. The server is the following C program:

#include stdio.h
#include string.h
main(int argc, char *argv[])

{

int tag = atoi(argv[1]);
        for (; ;) {
        sleep(5);
        write(1, &tag, sizeof(tag));
}

}

The following are the PV-WAVE procedures that use the above server:

PRO SERVER1, lun

code = 0L
READU, lun, code
PRINT, 'SERVER1', code

END
PRO SERVER2, lun

code = 0L
READU, lun, code
PRINT, 'SERVER2', code

END
PRO SERVER3, lun

code = 0L
READU, lun, code
PRINT, 'SERVER3', code

END
PRO EX1

; Start servers.

SPAWN, 'EX1 1', Unit = lun1, /Sh
SPAWN, 'EX1 2', Unit = lun2, /Sh
SPAWN, 'EX1 3', Unit = lun3, /Sh

; Handle servers.

EXEC_ON_SELECT, [lun1, lun2, lun3],  $
    ['SERVER1', 'SERVER2', 'SERVER3']

END

This example is an extension of the previous example. Again, three servers are started and their output handled using EXEC_ON_SELECT. The input is handled by the callback procedures SERVER1, SERVER2, SERVER3. Now, a widget menu also is displayed and serviced. The EXEC_ON_SELECT procedure registers the LUNs and callback procedures with the WAVE Widgets event loop (WwLoop) and returns values using the Widget and Just_reg keywords.

When there is input, WwLoop calls the appropriate callback routine to handle the input and returns to waiting for more input.

PRO SERVER1, top, data, nparams, id, lun,  $
    source

 code = 0L
 READU, lun, code
 PRINT, 'SERVER1', code, lun

END
PRO SERVER2, top, data, nparams, id, lun,  $
    source

 code = 0L
 READU, lun, code
 PRINT, 'SERVER2', code, lun

END
PRO SERVER3, top, data, nparams, id, lun, source

 code = 0L
 READU, lun, code
 PRINT, 'SERVER3', code, lun

END
PRO MenuCB, wid, index

; Create a menu.

 PRINT, 'Menu Item', index, ' selected.'
 value = WwGetValue(wid)
 PRINT, value

END
PRO Ex2

 SPAWN, 'EX1 1', unit = lun1, /sh
 SPAWN, 'EX1 2', unit = lun2, /sh
 SPAWN, 'EX1 3', unit = lun3, /sh

 top = WwInit('ex2','Test',layout,/Vertical)
 button = WwButtonBox(layout, ['Fonts', $
    'Size','Icons'],'MenuCB')
 status = WwSetValue(top, /Display)
 EXEC_ON_SELECT, [lun1, lun2, lun3], $

['SERVER1','SERVER2','SERVER3'], /Widget, $
    /Just_reg

 WwLoop
 CLOSE, lun1, lun2, lun3
END

ADD_EXEC_ON_SELECT, DROP_EXEC_ON_SELECT, SELECT_READ_LUN