POLY_C_CONV Function

Returns a list of colors for each polygon, given a polygon list and a list of colors for each vertex.

result = POLY_C_CONV(polygon_list, colors)

polygon_list An array containing a list of polygons. For more information, see Vertex Lists and Polygon Lists in Chapter 7 of the PV-WAVE User's Guide.

colors A vertex-based color list.

result An integer vector containing the list of colors, one color for each input polygon. (In other words, the result contains the same number of colors as the number of polygons in polygon_list.)

None.

POLY_C_CONV is useful for converting a vertex-based color list to a polygon-based list. For example, the SHADE_VOLUME procedure returns a list of polygon colors when the Shades keyword is used. This list has one color per vertex. The POLY_PLOT procedure, however, requires a color list with one color per polygon.

This example program displays data warped onto an irregular sphere.

PRO sphere_demo2
radii = RANDOMU(s, 60, 60)
radii = SMOOTH((radii + 1.0), 2)
POLY_SPHERE, radii, 60, 60, vertex_list, $
    polygon_list

; Define the sphere as a list of polygons.

p_colors = BYTSCL(DIST(60), Top=127)

; Define the shading colors for the sphere.

WINDOW, 0, Colors=128, XPos=16, YPos=384
LOADCT, 1
CENTER_VIEW, Xr=[-2.0, 2.0], $
    Yr=[-2.0, 2.0], Zr=[-2.0, 2.0], $
    Ax=(-75.0), Az=(-90.0), Zoom=0.99

; Set up the viewing window and load the color table.

TVSCL, POLYSHADE(vertex_list, polygon_list, $
    /T3d, Shade=p_colors)

; Construct a shaded surface representation of the data and
; display it using POLYSHADE.

WINDOW, 1, Colors = 128, XPos = 256, YPos = 64

; Create a new window for a new plot.

pg_num = POLY_COUNT(polygon_list)

; Count the number of polygons in the sphere.

vertex_list = POLY_NORM(vertex_list)
vertex_list = POLY_TRANS(vertex_list, !P.T)
vertex_list = POLY_DEV(vertex_list, 640, 512)

; Transform the polygon vertices from data coordinates to device
; coordinates.

p_colors = POLY_C_CONV(polygon_list, p_colors(*))

; Convert the colors from a vertex-based list to a polygon-based
; list.

POLY_PLOT, vertex_list, polygon_list, $
     pg_num, 640, 512, p_colors, 0, -1

; Plot the sphere using POLY_PLOT.

END

For another POLY_C_CONV example, see the poly_demo1 demonstration program in:

(UNIX)wavedir/demo/arl

(OpenVMS)wavedir:[DEMO.ARL]

(Windows)wavedir\demo\arl

Where wavedir is the main PV-WAVE directory.

POLY_PLOT, POLYSHADE, SHADE_VOLUME